<PROGRAM> ::= <DEFINITIONS>

<DEFINITIONS> ::= **ε**

| <DEF> <DEFINITIONS>

<DEF> ::= **function** <IDENTIFIER> **(** <FORMALS> **) :** <TYPE>

<BODY>

<FORMALS> ::= **ε**

| <NONEMPTYFORMALS>

<NONEMPTYFORMALS> ::= <FORMAL>

| <FORMAL> **,** <NONEMPTYFORMALS>

<FORMAL> ::= <IDENTIFIER> **:** <TYPE>

<BODY> ::= <PRINT-STATEMENT> <BODY>

| <EXPR>

<TYPE> ::= **integer**

| **boolean**

<EXPR> ::= <SIMPLE-EXPR> <EXPR-TAIL>

<EXPR-TAIL> ::= **<** <SIMPLE-EXPR>

| **=** <SIMPLE-EXPR>

| **ε**

<SIMPLE-EXPR> ::= <TERM> <SIMPLE-EXPR-TAIL>

<SIMPLE-EXPR-TAIL> ::= **or** <TERM>

| **+** <TERM>

| **-** <TERM>

| **ε**

<TERM> ::= <FACTOR> <TERM-TAIL>

<TERM-TAIL> ::= **and** <FACTOR>

| **\*** <FACTOR>

| **/** <FACTOR>

| **ε**

<FACTOR> ::= **if** <EXPR> **then** <EXPR> **else** <EXPR>

| **not** <FACTOR>

| <IDENTIFIER> **(** <ACTUALS> **)**

| <IDENTIFIER>

| <LITERAL>

| **-** <FACTOR>

| **(** <EXPR> **)**

<ACTUALS> ::= **ε**

| <NONEMPTYACTUALS>

<NONEMPTYACTUALS> ::= <EXPR>

| <EXPR> **,** <NONEMPTYACTUALS>

<LITERAL> ::= <NUMBER>

| <BOOLEAN>

<PRINT-STATEMENT> ::= **print (** <EXPR> **)**